Revision control
Copy as Markdown
// Copyright (C) 2026 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
// Installed by Coin into $GRADLE_USER_HOME/init.d to route every gradle
// invocation's repositories through the internal Nexus mirror.
def addMirror = { repositories ->
repositories.maven { mavenRepository ->
mavenRepository.name = 'qt-nexus-mirror'
mavenRepository.url = mirror
}
}
def enforceMirror = { repositories ->
repositories.all { repository ->
if (repository.name != 'qt-nexus-mirror')
repositories.remove(repository)
}
addMirror(repositories)
}
// Modern templates: replace the settings-level repositories with the mirror.
settingsEvaluated { settings ->
settings.pluginManagement.repositories.clear()
addMirror(settings.pluginManagement.repositories)
settings.dependencyResolutionManagement {
repositoriesMode.set(RepositoriesMode.PREFER_PROJECT)
repositories.clear()
addMirror(repositories)
}
}
// Legacy templates: replace the buildscript and project repositories with the mirror.
allprojects { project ->
enforceMirror(project.buildscript.repositories)
enforceMirror(project.repositories)
}