Revision control
Copy as Markdown
// Copyright (C) 2024 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
#version 440
#extension GL_GOOGLE_include_directive : enable
#include "uniformbuffer.glsl"
#include "colortransfer.glsl"
#include "colorconvert.glsl"
#include "hdrtonemapper.glsl"
#include "texturecomponent.glsl"
layout(location = 0) in vec2 texCoord;
layout(location = 0) out vec4 fragColor;
layout(binding = 1) uniform sampler2D plane1Texture;
layout(binding = 2) uniform sampler2D plane2Texture;
// This implements support HDR video using the HLG transfer functions, see also
//
// Tonemapping is done using the same algorithm as for the PQ transfer function, but we
// operate in HLG space here.
void main()
{
float Y = getR16(plane1Texture, texCoord, ubuf.plane1Format, 1);
vec2 UV = getRG16(plane2Texture, texCoord, ubuf.plane2Format);
// map to Rec.2020 color space
fragColor = vec4(Y, UV.x, UV.y, 1.);
fragColor = ubuf.colorMatrix * fragColor;
// tonemap
float y = (Y - 16./256.)*256./219.; // Video range (16...235)
float scale = tonemapScaleForLuminosity(y, ubuf.masteringWhite, ubuf.maxLum);
fragColor *= scale;
fragColor = convertHLGToLinear(fragColor, ubuf.maxLum);
fragColor = convertRec2020ToSRGB(fragColor);
fragColor *= ubuf.opacity;
#ifndef QMM_OUTPUTSURFACE_LINEAR
fragColor = convertSRGBFromLinear(fragColor);
#endif
}