Revision control

++ qtPrepareLibExecTool(QMAKE_RCC, rcc, _DEP)
++
++ isEmpty(QMAKE_MOD_RCC):QMAKE_MOD_RCC = qrc
++
++ !contains(QMAKE_RESOURCE_FLAGS, -root):!isEmpty(QMAKE_RESOURCE_ROOT):QMAKE_RESOURCE_FLAGS += -root $$QMAKE_RESOURCE_ROOT
++ !contains(QMAKE_RESOURCE_FLAGS, -name): QMAKE_RESOURCE_FLAGS += -name ${QMAKE_FILE_BASE}
++ !qtConfig(zstd): QMAKE_RESOURCE_FLAGS += --no-zstd
++
++ load(resources_functions)
++ qtFlattenResources()
++ qtEnsurePluginResourcesCpp()
++
++ rcc.input = RESOURCES
++ rcc.name = RCC ${QMAKE_FILE_IN}
++ rcc.depend_command = $$QMAKE_RCC_DEP -list $$QMAKE_RESOURCE_FLAGS ${QMAKE_FILE_IN}
++ rcc.CONFIG += add_inputs_as_makefile_deps dep_lines remove_no_exist
++
++ !resources_big|ltcg|macx-xcode|wasm|contains(TEMPLATE, "vc.*") {
++
++ rcc.output = $$RCC_DIR/$${first(QMAKE_MOD_RCC)}_${QMAKE_FILE_BASE}$${first(QMAKE_EXT_CPP)}
++ rcc.commands = $$QMAKE_RCC $$QMAKE_RESOURCE_FLAGS ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
++ rcc.variable_out = SOURCES
++
++ } else {
++
++ isEmpty(RCC_CXX) {
++ RCC_CXX = $$QMAKE_CXX $(CXXFLAGS)
++ # -pass 2 needs a regular object file to patch, not LTO bytecode.
++ clang_cl|gcc|clang: RCC_CXX += -fno-lto
++ else:msvc: RCC_CXX += -GL-
++ }
++ RCC_OUT_BASE = $$RCC_DIR/$${first(QMAKE_MOD_RCC)}_${QMAKE_FILE_BASE}
++ RCC_CPP = $$RCC_OUT_BASE$${first(QMAKE_EXT_CPP)}
++ RCC_TMP = $${RCC_OUT_BASE}.tmp$${first(QMAKE_EXT_OBJ)}
++ RCC_OBJ = $$RCC_OUT_BASE$${first(QMAKE_EXT_OBJ)}
++
++ msvc: RCC_CXX_O_FLAG = "-Fo"
++ else: RCC_CXX_O_FLAG = "-o "
++
++ rcc.output = $$RCC_OBJ
++ rcc.commands = \
++ $$QMAKE_RCC $$QMAKE_RESOURCE_FLAGS ${QMAKE_FILE_IN} -pass 1 -o $$RCC_CPP && \
++ $$RCC_CXX -c $$RCC_CPP $$RCC_CXX_O_FLAG$$RCC_TMP && \
++ $$QMAKE_RCC $$QMAKE_RESOURCE_FLAGS ${QMAKE_FILE_IN} -pass 2 -temp $$RCC_TMP -o ${QMAKE_FILE_OUT}
++ rcc.clean += $$RCC_CPP $$RCC_TMP
++
++ }
++
++ rcc.depends += $$QMAKE_RCC_EXE
++ silent:rcc.commands = @echo rcc ${QMAKE_FILE_IN} && $$rcc.commands
++ else:rcc.commands ~= s/&&/$$escape_expand(\\n\\t)/g
++ QMAKE_EXTRA_COMPILERS += rcc