Revision control
++ // Copyright (C) 2017 The Qt Company Ltd.
++ // SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
++ // Qt-Security score:significant reason:default
++
++ import QtQuick
++ import QtQuick.Controls.impl
++ import QtQuick.Controls.Basic.impl
++ import QtQuick.Templates as T
++
++ T.TextArea {
++ id: control
++
++ implicitWidth: Math.max(contentWidth + leftPadding + rightPadding,
++ implicitBackgroundWidth + leftInset + rightInset,
++ placeholder.implicitWidth + leftPadding + rightPadding)
++ implicitHeight: Math.max(contentHeight + topPadding + bottomPadding,
++ implicitBackgroundHeight + topInset + bottomInset,
++ placeholder.implicitHeight + topPadding + bottomPadding)
++
++ padding: 6
++ leftPadding: padding + 4
++
++ color: control.palette.text
++ placeholderTextColor: control.palette.placeholderText
++ selectionColor: control.palette.highlight
++ selectedTextColor: control.palette.highlightedText
++
++ ContextMenu.menu: TextEditingContextMenu {
++ editor: control
++ }
++
++ background: Rectangle {
++ visible: Qt.styleHints.accessibility.contrastPreference === Qt.HighContrast
++ color: "transparent"
++ border.width: control.activeFocus ? 2 : 1
++ border.color: control.activeFocus ? control.palette.highlight :
++ control.enabled ? control.palette.mid : control.palette.midlight
++ }
++
++ PlaceholderText {
++ id: placeholder
++ x: control.leftPadding
++ y: control.topPadding
++ width: control.width - (control.leftPadding + control.rightPadding)
++ height: control.height - (control.topPadding + control.bottomPadding)
++
++ text: control.placeholderText
++ font: control.font
++ color: control.placeholderTextColor
++ verticalAlignment: control.verticalAlignment
++ visible: !control.length && !control.preeditText && (!control.activeFocus || control.horizontalAlignment !== Qt.AlignHCenter)
++ wrapMode: control.wrapMode
++ elide: Text.ElideRight
++ renderType: control.renderType
++ }
++ }