Revision control
++ // Copyright (C) 2017 The Qt Company Ltd.
++ // SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
++ // Qt-Security score:significant reason:default
++
++ import QtQuick
++ import QtQuick.Controls.impl
++ import QtQuick.Templates as T
++
++ T.ScrollBar {
++ id: control
++
++ implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
++ implicitContentWidth + leftPadding + rightPadding)
++ implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
++ implicitContentHeight + topPadding + bottomPadding)
++
++ padding: 2
++ visible: control.policy !== T.ScrollBar.AlwaysOff
++ minimumSize: orientation === Qt.Horizontal ? height / width : width / height
++
++ contentItem: Rectangle {
++ implicitWidth: control.interactive ? 6 : 2
++ implicitHeight: control.interactive ? 6 : 2
++
++ radius: width / 2
++ color: {
++ if (Qt.styleHints.accessibility.contrastPreference !== Qt.HighContrast)
++ return pressed ? control.palette.dark : control.palette.mid
++ else
++ return Color.blend(control.palette.text, control.palette.mid, pressed ? 0.0 : 0.3)
++ }
++
++ opacity: 0.0
++
++ states: State {
++ name: "active"
++ when: control.policy === T.ScrollBar.AlwaysOn || (control.active && control.size < 1.0)
++ PropertyChanges { control.contentItem.opacity: 0.75 }
++ }
++
++ transitions: Transition {
++ from: "active"
++ SequentialAnimation {
++ PauseAnimation { duration: 450 }
++ NumberAnimation { target: control.contentItem; duration: 200; property: "opacity"; to: 0.0 }
++ }
++ }
++ }
++
++ background: Rectangle {
++ visible: Qt.styleHints.accessibility.contrastPreference === Qt.HighContrast
++ opacity: control.contentItem.opacity
++ color: control.palette.mid
++ }
++ }